批处理（bat）实现全盘搜索指定文件获取其完整路径方法大全

脚本专栏发布日期：2024/10/19 浏览次数：1

正在浏览：批处理（bat）实现全盘搜索指定文件获取其完整路径方法大全

废话不多说，直接上代码，额，想用的话，自己保存成bat文件即可。

【方案一】for /f + dir

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
      )
    )
  )
)

【方案二】for /r（比 for /f + dir 效率高，但不会遍历隐藏文件）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    pushd %%a:    for /r %%b in (*%FileName%) do (
      if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
      )
    )
    popd
  )
)

【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精简版可能不支持）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in ("%FileName%") do (
  set "nName=%%~na"
  set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
  echo,%%a
)

【方案四】使用 Windows7 系统自带的 where 命令

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
      )
    )
  )
)

上一篇：用批处理修改日期然后在改回来

下一篇：清理IE和使用历史记录的bat代码

一句话新闻

微软与英特尔等合作伙伴联合定义“AI PC”：键盘需配有Copilot物理按键

几个月来，英特尔、微软、AMD和其它厂商都在共同推动“AI PC”的想法，朝着更多的AI功能迈进。在近日，英特尔在台北举行的开发者活动中，也宣布了关于AI PC加速计划、新的PC开发者计划和独立硬件供应商计划。
在此次发布会上，英特尔还发布了全新的全新的酷睿Ultra Meteor Lake NUC开发套件，以及联合微软等合作伙伴联合定义“AI PC”的定义标准。